Рис. 25.1. Вычисление N отсчетов спектра сигнала с помощью ДПФ
В квадратных скобках уравнения присутствуют коэффициенты для действительной и мнимой частей.
Рассмотрим очередной пример программы, демонстрирующей реализацию метода дискретного преобразования Фурье для получения спектра сигнала в среде Visual DSP++. Откройте в программном пакете Visual DSP++ очередной проект из каталога C:\Program Files\AnalogDevices\VisualDSP\218x\Examples\Example4 и разверните в нем программу, находящуюся в файле с именем "Dft.asm". В этой программе производится расчет спектра сигнала по N отсчетам сигнала, используя алгоритм дискретного преобразования Фурье. Текст этой программы с переведенными автором книги комментариями приведен ниже:
/*====================================================================
Файл:DFT.ASM Процессор:ADSP-218х Дискретное Преобразование Фурье (ДПФ)
Эта программа выполняет ДПФ для N точек согласно следующему уравнению:
N-1
real(k)+j *imag(k) = SUM input(n) [С - j*S]; k=0 до N-1
n=0
где: C=cos(2*pi*k*n/N), S=sin(2*pi*k*n/N), j=sqrt(-1)
====================================================================*/
#define N 64 /* Константа - количество входных отсчетов * /
#define COS 0x000C1 /* Адрес буфера временных данных COS */
#define SIN 0x000C5 /* Адрес буфера временных данных SIN */
.section/data data1;
.VAR input[N]=etest64.date; /* Таблица данных тестируемого сигнала */
.VAR real[N]; /* Буфер действительных значений спектра * /
.VAR imag[N]; /* Буфер мнимых значений спектра */
.section/pm pm_da;
.VAR sine[N]="sine64.dat";/* Таблица данных гармонического сигнала */
.section/pm interrupts;
__reset: JUMP start; rti; rti; rti; /* 0x0000: reset */
rti; rti; rti; rti; /* 0x0004: IRQ2 */
rti; rti; rti; rti; /* 0x0008: IRQL1 */
rti; rti; rti; rti; /* 0x000c: IRQL0 */
rti; rti; rti; rti; /* 0x0010: SPORT0 tx */
rti; rti; rti; rti; /* 0x0014: SPORT1 rx */
rti; rti; rti; rti; /* 0x0018: IRQE */
rti; rti; rti; rti; /* 0x001c: BDMA */
rti; rti; rti; rti; /* 0x0020: SPORT1 tx or IRQ1 */
rti; rti; rti; rti; /* 0x0024: SPORT1 rx or IRQ0 */
rti; rti; rti; rti; /* 0x0028: timer */
rti; rti; rti; rti; /* 0x002c: power down */
.section/pm seg_code; /* Пример установки программы ДПФ */
start:
M1=1;
M2=0;
M7=1;
M5=0;
I0=input;
L0=64; /* Входной буфер циклический */
I1=imag;
L1=0; /* Нециклический буфер Image */
I2=real;
L2=0; /* Нециклический буфер Real */
/* ______________Подпрограмма ДПФ_____________________ */
dft:
I6=sine; /* Указатель на Sine */
L6=64; /* Для N=64 значений */
I7=sine + N/4; /* Получение косинуса из синуса */
L7=64; /* Сдвиг указателя на pi/2 */
/* и использование циклического буфера.*/
I4=COS;
L4=2;
I3=SIN;
L3=2;
I5=0;
L5=0;
CNTR=N;
DO outer UNTIL CE;
M6=I5;
DM(I4,M7)=0; DM(I4,M7)=0;/* Очистка буфера временных данных COS */
DM(I3,M1)=0; DM(I3,M1)=0;/* Очистка буфера временных данных SIN */
CNTR=N;
DO calc UNTIL CE;
MX0=DM(I0,M1), MY0=PM(I7,M6); /* Чтение input, чтение COS */
MX1=MX0 /* Копирование input */
MY1=PM(I6,M6); /* Чтение SIN */
MR1=DM(I4,M7); /* Чтение текущего значения COS и суммирование */
MR0=DM(I4,M7);
MR=MR+MX0*MY0(SS);/* Мультисуммирование COS */
DM(I4,M7)=MR1; /* Запись нового накопленного значения COS */
DM(I4,M7)=MR0;
MR1=DM(I3,M1); /* Чтение текущего значения SIN и суммирование */
MR0=DM(I3,M1);
MR=MR-MX1*MY1(SS);/* Мультисуммирование SIN */
DM(I3,M1)=MR1; /* Запись нового накопленного значения SIN */
calc : DM(I3,M1)=MR0;
AR=DM(I4,M5);
DM(I2,M1)=AR; /* Запись результата действующей величины * /
AR=DM(I3,M2);
DM(I1,M1)=AR; /* Запись результата мнимой величины */
outer: MODIFY(I5,M7); /* Модификация указателей циклической таблицы */
end: IDLE;
Как видно из текста программы, в ней задействованы регистры генераторов адреса DAG для задания указателей на буфер данных тестируемого сигнала, таблицу значений гармонического сигнала, буферы результата и другие вспомогательные буферы. Вычисление значений спектра производится в двух циклах, счетчики которых инициализируются числом отсчетов N = 64. Вся программа выполняется за N*N групп операций. Результат работы программы заносится в выходные буферы действительных значений real и мнимых значений imag спектра.
Для выполнения программы выполните ее трансляцию с помощью клавиши F7. Затем установите точку останова на последнем операторе программы и запустите ее с помощью клавиши F5. Через несколько секунд программа выполнит свою работу и остановится. Визуальный просмотр тестируемого сигнала, а также результатов работы программы и других вспомогательных буферов данных можно осуществлять с помощью открытия окна памяти данных процессора, используя для этого команду Memory→Data. Кроме того, эти данные можно просматривать в графическом виде. Для этого необходимо выполнить команду: View→Debug Windows→Plot→New. При этом откроется окно конфигурации графического построителя Plot Configuration, показанное на рис. 25.2.
Рис. 25.2. Окно конфигурации графического построителя Plot Configuration
Рассмотрим работу с данным конфигуратором на примере просмотра буфера данных тестируемого сигнала. Оставьте в открывшемся окне конфигуратора без изменений строку Line Plot в поле Type группы настроек Plot. В поле Title введите имя графика "Input" или другое схожее по смыслу.
В группе Data Setting оставьте без изменений имя Data Set1 в поле Name и тип памяти DM в поле Memory. Нажмите на кнопку Browse в поле Address и выделите в открывшемся окне Browse for Symbol строку с именем input (рис. 25.3), после чего нажмите кнопку OK.
Рис. 25.3
В поле смещения данных Offset оставьте нулевое значение, а в поле счетчика Count замените значение 100 на 64, что соответствует количеству отсчетов в программе. Оставьте шаг сетки в поле Stride по умолчанию равным 1, а формат данных в поле Data целочисленным int. Нажмите на кнопку Add для добавления заданных установок в поле Data sets графического построителя. При желании, в это поле можно добавить и другие данные для отображения, а затем установить или снять перед соответствующим именем графика флажок для отображения этого графика. Теперь, нажмите на кнопку OK, после чего в правой части окна Visual DSP++ отобразится график заданных данных (рис. 25.4).